deepseq-1.4.1.1: Deep evaluation of data structures

Copyright | (c) The University of Glasgow 2001-2009
License | BSD-style (see the file LICENSE)
Maintainer | libraries@haskell.org
Stability | stable
Portability | portable
Safe Haskell | Safe
Language | Haskell2010

Control.DeepSeq

Description

This module provides an overloaded function, `deepseq`, for fully evaluating data structures (that is, evaluating to "Normal Form").

A typical use is to prevent resource leaks in lazy IO programs, by forcing all characters from a file to be read. For example:

    import System.IO
    import Control.DeepSeq

    main = do
        h <- openFile "f" ReadMode
        s <- hGetContents h
        s `deepseq` hClose h
        return s

`deepseq` differs from `seq` as it traverses data structures deeply, for example, `seq` will evaluate only to the first constructor in the list:

    > [1,2,undefined] `seq` 3
    3

While `deepseq` will force evaluation of all the list elements:

    > [1,2,undefined] `deepseq` 3
    *** Exception: Prelude.undefined

Another common use is to ensure any exceptions hidden within lazy fields of a data structure do not leak outside the scope of the exception handler, or to force evaluation of a data structure in one thread, before passing to another thread (preventing work moving to the wrong threads).

Since: 1.1.0.0

Synopsis

- deepseq :: NFData a => a -> b -> b
- ($!!) :: NFData a => (a -> b) -> a -> b
- force :: NFData a => a -> a
- class NFData a where
  - rnf :: a -> ()

# Documentation

deepseq :: NFData a => a -> b -> b

`deepseq`: fully evaluates the first argument, before returning the second.

The name `deepseq` is used to illustrate the relationship to `seq`: where `seq` is shallow in the sense that it only evaluates the top level of its argument, `deepseq` traverses the entire data structure evaluating it completely.

`deepseq` can be useful for forcing pending exceptions, eradicating space leaks, or forcing lazy I/O to happen. It is also useful in conjunction with parallel Strategies (see the `parallel` package).

There is no guarantee about the ordering of evaluation. The implementation may evaluate the components of the structure in any order or in parallel. To impose an actual order on evaluation, use `pseq` from Control.Parallel in the `parallel` package.

Since: 1.1.0.0

($!!) :: NFData a => (a -> b) -> a -> b infixr 0

the deep analogue of `$!`. In the expression `f $!! x`, `x` is fully evaluated before the function `f` is applied to it.

Since: 1.2.0.0

force :: NFData a => a -> a

a variant of `deepseq` that is useful in some circumstances:

    force x = x `deepseq` x

`force x` fully evaluates `x`, and then returns it. Note that `force x` only performs evaluation when the value of `force x` itself is demanded, so essentially it turns shallow evaluation into deep evaluation.

`force` can be conveniently used in combination with `ViewPatterns`:

    {-# LANGUAGE BangPatterns, ViewPatterns #-}
    import Control.DeepSeq

    someFun :: ComplexData -> SomeResult
    someFun (force -> !arg) = {- 'arg' will be fully evaluated -}

Another useful application is to combine `force` with `evaluate` in order to force deep evaluation relative to other `IO` operations:

    import Control.Exception (evaluate)
    import Control.DeepSeq

    main = do
      result <- evaluate $ force $ pureComputation
      {- 'result' will be fully evaluated at this point -}
      return ()

Since: 1.2.0.0

class NFData a where

A class of types that can be fully evaluated.

Since: 1.1.0.0

Minimal complete definition

Nothing

Methods

rnf :: a -> ()

`rnf` should reduce its argument to normal form (that is, fully evaluate all sub-components), and then return '()'.

### `Generic` `NFData` deriving

Starting with GHC 7.2, you can automatically derive instances for types possessing a `Generic` instance.

    {-# LANGUAGE DeriveGeneric #-}

    import GHC.Generics (Generic)
    import Control.DeepSeq

    data Foo a = Foo a String
                 deriving (Eq, Generic)

    instance NFData a => NFData (Foo a)

    data Colour = Red | Green | Blue
                  deriving Generic

    instance NFData Colour

Starting with GHC 7.10, the example above can be written more concisely by enabling the new `DeriveAnyClass` extension:

    {-# LANGUAGE DeriveGeneric, DeriveAnyClass #-}

    import GHC.Generics (Generic)
    import Control.DeepSeq

    data Foo a = Foo a String
                 deriving (Eq, Generic, NFData)

    data Colour = Red | Green | Blue
                  deriving (Generic, NFData)

### Compatibility with previous `deepseq` versions

Prior to version 1.4.0.0, the default implementation of the `rnf` method was defined as

    rnf a = seq a ()

However, starting with `deepseq-1.4.0.0`, the default implementation is based on `DefaultSignatures` allowing for more accurate auto-derived `NFData` instances. If you need the previously used exact default `rnf` method implementation semantics, use

    instance NFData Colour where rnf x = seq x ()

or alternatively

    {-# LANGUAGE BangPatterns #-}
    instance NFData Colour where rnf !_ = ()

Instances

NFData Bool |
NFData Char |
NFData Double |
NFData Float |
NFData Int |
NFData Int8 |
NFData Int16 |
NFData Int32 |
NFData Int64 |
NFData Integer |
NFData Word |
NFData Word8 |
NFData Word16 |
NFData Word32 |
NFData Word64 |
NFData TypeRep | NOTE: Only defined for `base-4.8.0.0` and later Since: 1.4.0.0
NFData () |
NFData Void | Defined as ``rnf` = `absurd``. Since: 1.4.0.0
NFData Unique | Since: 1.4.0.0
NFData Natural | Since: 1.4.0.0
NFData Version | Since: 1.3.0.0
NFData ThreadId | Since: 1.4.0.0
NFData CChar | Since: 1.4.0.0
NFData CSChar | Since: 1.4.0.0
NFData CUChar | Since: 1.4.0.0
NFData CShort | Since: 1.4.0.0
NFData CUShort | Since: 1.4.0.0
NFData CInt | Since: 1.4.0.0
NFData CUInt | Since: 1.4.0.0
NFData CLong | Since: 1.4.0.0
NFData CULong | Since: 1.4.0.0
NFData CLLong | Since: 1.4.0.0
NFData CULLong | Since: 1.4.0.0
NFData CFloat | Since: 1.4.0.0
NFData CDouble | Since: 1.4.0.0
NFData CPtrdiff | Since: 1.4.0.0
NFData CSize | Since: 1.4.0.0
NFData CWchar | Since: 1.4.0.0
NFData CSigAtomic | Since: 1.4.0.0
NFData CClock | Since: 1.4.0.0
NFData CTime | Since: 1.4.0.0
NFData CUSeconds | Since: 1.4.0.0
NFData CSUSeconds | Since: 1.4.0.0
NFData CFile | Since: 1.4.0.0
NFData CFpos | Since: 1.4.0.0
NFData CJmpBuf | Since: 1.4.0.0
NFData CIntPtr | Since: 1.4.0.0
NFData CUIntPtr | Since: 1.4.0.0
NFData CIntMax | Since: 1.4.0.0
NFData CUIntMax | Since: 1.4.0.0
NFData All | Since: 1.4.0.0
NFData Any | Since: 1.4.0.0
NFData TyCon | NOTE: Only defined for `base-4.8.0.0` and later Since: 1.4.0.0
NFData Fingerprint | Since: 1.4.0.0
NFData a => NFData [a] |
(Integral a, NFData a) => NFData (Ratio a) |
NFData (StableName a) | Since: 1.4.0.0
NFData a => NFData (Identity a) | Since: 1.4.0.0
NFData (Fixed a) | Since: 1.3.0.0
NFData a => NFData (Complex a) |
NFData a => NFData (ZipList a) | Since: 1.4.0.0
NFData a => NFData (Dual a) | Since: 1.4.0.0
NFData a => NFData (Sum a) | Since: 1.4.0.0
NFData a => NFData (Product a) | Since: 1.4.0.0
NFData a => NFData (First a) | Since: 1.4.0.0
NFData a => NFData (Last a) | Since: 1.4.0.0
NFData a => NFData (Down a) | Since: 1.4.0.0
NFData a => NFData (Maybe a) |
NFData (a -> b) | This instance is for convenience and consistency with `seq`. This assumes that WHNF is equivalent to NF for functions. Since: 1.3.0.0
(NFData a, NFData b) => NFData (Either a b) |
(NFData a, NFData b) => NFData (a, b) |
(Ix a, NFData a, NFData b) => NFData (Array a b) |
NFData a => NFData (Const a b) | Since: 1.4.0.0
NFData (Proxy * a) | Since: 1.4.0.0
(NFData a, NFData b, NFData c) => NFData (a, b, c) |
(NFData a, NFData b, NFData c, NFData d) => NFData (a, b, c, d) |
(NFData a1, NFData a2, NFData a3, NFData a4, NFData a5) => NFData (a1, a2, a3, a4, a5) |
(NFData a1, NFData a2, NFData a3, NFData a4, NFData a5, NFData a6) => NFData (a1, a2, a3, a4, a5, a6) |
(NFData a1, NFData a2, NFData a3, NFData a4, NFData a5, NFData a6, NFData a7) => NFData (a1, a2, a3, a4, a5, a6, a7) |
(NFData a1, NFData a2, NFData a3, NFData a4, NFData a5, NFData a6, NFData a7, NFData a8) => NFData (a1, a2, a3, a4, a5, a6, a7, a8) |
(NFData a1, NFData a2, NFData a3, NFData a4, NFData a5, NFData a6, NFData a7, NFData a8, NFData a9) => NFData (a1, a2, a3, a4, a5, a6, a7, a8, a9) |