base-4.8.2.0: Basic libraries

Copyright | (c) The University of Glasgow 2002
License | BSD-style (see the file libraries/base/LICENSE)
Maintainer | libraries@haskell.org
Stability | provisional
Portability | non-portable (local universal quantification)
Safe Haskell | Trustworthy
Language | Haskell2010

Text.ParserCombinators.ReadP

Contents

- The `ReadP` type
- Primitive operations
- Other operations
- Running a parser
- Properties

Description

This is a library of parser combinators, originally written by Koen Claessen. It parses all alternatives in parallel, so it never keeps hold of the beginning of the input string, a common source of space leaks with other parsers. The '(+++)' choice combinator is genuinely commutative; it makes no difference which branch is "shorter".

Synopsis

- data ReadP a
- get :: ReadP Char
- look :: ReadP String
- (+++) :: ReadP a -> ReadP a -> ReadP a
- (<++) :: ReadP a -> ReadP a -> ReadP a
- gather :: ReadP a -> ReadP (String, a)
- pfail :: ReadP a
- eof :: ReadP ()
- satisfy :: (Char -> Bool) -> ReadP Char
- char :: Char -> ReadP Char
- string :: String -> ReadP String
- munch :: (Char -> Bool) -> ReadP String
- munch1 :: (Char -> Bool) -> ReadP String
- skipSpaces :: ReadP ()
- choice :: [ReadP a] -> ReadP a
- count :: Int -> ReadP a -> ReadP [a]
- between :: ReadP open -> ReadP close -> ReadP a -> ReadP a
- option :: a -> ReadP a -> ReadP a
- optional :: ReadP a -> ReadP ()
- many :: ReadP a -> ReadP [a]
- many1 :: ReadP a -> ReadP [a]
- skipMany :: ReadP a -> ReadP ()
- skipMany1 :: ReadP a -> ReadP ()
- sepBy :: ReadP a -> ReadP sep -> ReadP [a]
- sepBy1 :: ReadP a -> ReadP sep -> ReadP [a]
- endBy :: ReadP a -> ReadP sep -> ReadP [a]
- endBy1 :: ReadP a -> ReadP sep -> ReadP [a]
- chainr :: ReadP a -> ReadP (a -> a -> a) -> a -> ReadP a
- chainl :: ReadP a -> ReadP (a -> a -> a) -> a -> ReadP a
- chainl1 :: ReadP a -> ReadP (a -> a -> a) -> ReadP a
- chainr1 :: ReadP a -> ReadP (a -> a -> a) -> ReadP a
- manyTill :: ReadP a -> ReadP end -> ReadP [a]
- type ReadS a = String -> [(a, String)]
- readP_to_S :: ReadP a -> ReadS a
- readS_to_P :: ReadS a -> ReadP a

# The `ReadP` type

data ReadP a

Instances

Monad ReadP |
Functor ReadP |
Applicative ReadP |
MonadPlus ReadP |
Alternative ReadP |

# Primitive operations

get :: ReadP Char

Consumes and returns the next character. Fails if there is no input left.

look :: ReadP String

Look-ahead: returns the part of the input that is left, without consuming it.

(+++) :: ReadP a -> ReadP a -> ReadP a infixr 5

Symmetric choice.

(<++) :: ReadP a -> ReadP a -> ReadP a infixr 5

Local, exclusive, left-biased choice: If left parser locally produces any result at all, then right parser is not used.

gather :: ReadP a -> ReadP (String, a)

Transforms a parser into one that does the same, but in addition returns the exact characters read. IMPORTANT NOTE: `gather` gives a runtime error if its first argument is built using any occurrences of readS_to_P.

# Other operations

pfail :: ReadP a

Always fails.

eof :: ReadP ()

Succeeds iff we are at the end of input

satisfy :: (Char -> Bool) -> ReadP Char

Consumes and returns the next character, if it satisfies the specified predicate.

char :: Char -> ReadP Char

Parses and returns the specified character.

string :: String -> ReadP String

Parses and returns the specified string.

munch :: (Char -> Bool) -> ReadP String

Parses the first zero or more characters satisfying the predicate. Always succeds, exactly once having consumed all the characters Hence NOT the same as (many (satisfy p))

munch1 :: (Char -> Bool) -> ReadP String

Parses the first one or more characters satisfying the predicate. Fails if none, else succeeds exactly once having consumed all the characters Hence NOT the same as (many1 (satisfy p))

skipSpaces :: ReadP ()

Skips all whitespace.

choice :: [ReadP a] -> ReadP a

Combines all parsers in the specified list.

count :: Int -> ReadP a -> ReadP [a]

`count n p` parses `n` occurrences of `p` in sequence. A list of results is returned.

between :: ReadP open -> ReadP close -> ReadP a -> ReadP a

`between open close p` parses `open`, followed by `p` and finally `close`. Only the value of `p` is returned.

option :: a -> ReadP a -> ReadP a

`option x p` will either parse `p` or return `x` without consuming any input.

optional :: ReadP a -> ReadP ()

`optional p` optionally parses `p` and always returns `()`.

many :: ReadP a -> ReadP [a]

Parses zero or more occurrences of the given parser.

many1 :: ReadP a -> ReadP [a]

Parses one or more occurrences of the given parser.

skipMany :: ReadP a -> ReadP ()

Like `many`, but discards the result.

skipMany1 :: ReadP a -> ReadP ()

Like `many1`, but discards the result.

sepBy :: ReadP a -> ReadP sep -> ReadP [a]

`sepBy p sep` parses zero or more occurrences of `p`, separated by `sep`. Returns a list of values returned by `p`.

sepBy1 :: ReadP a -> ReadP sep -> ReadP [a]

`sepBy1 p sep` parses one or more occurrences of `p`, separated by `sep`. Returns a list of values returned by `p`.

endBy :: ReadP a -> ReadP sep -> ReadP [a]

`endBy p sep` parses zero or more occurrences of `p`, separated and ended by `sep`.

endBy1 :: ReadP a -> ReadP sep -> ReadP [a]

`endBy p sep` parses one or more occurrences of `p`, separated and ended by `sep`.

chainr :: ReadP a -> ReadP (a -> a -> a) -> a -> ReadP a

`chainr p op x` parses zero or more occurrences of `p`, separated by `op`. Returns a value produced by a right associative application of all functions returned by `op`. If there are no occurrences of `p`, `x` is returned.

chainl :: ReadP a -> ReadP (a -> a -> a) -> a -> ReadP a

`chainl p op x` parses zero or more occurrences of `p`, separated by `op`. Returns a value produced by a left associative application of all functions returned by `op`. If there are no occurrences of `p`, `x` is returned.

chainl1 :: ReadP a -> ReadP (a -> a -> a) -> ReadP a

Like `chainl`, but parses one or more occurrences of `p`.

chainr1 :: ReadP a -> ReadP (a -> a -> a) -> ReadP a

Like `chainr`, but parses one or more occurrences of `p`.

manyTill :: ReadP a -> ReadP end -> ReadP [a]

`manyTill p end` parses zero or more occurrences of `p`, until `end` succeeds. Returns a list of values returned by `p`.

# Running a parser

type ReadS a = String -> [(a, String)]

A parser for a type `a`, represented as a function that takes a `String` and returns a list of possible parses as `(a,`String`)` pairs.

Note that this kind of backtracking parser is very inefficient; reading a large structure may be quite slow (cf `ReadP`).

readP_to_S :: ReadP a -> ReadS a

Converts a parser into a Haskell ReadS-style function. This is the main way in which you can "run" a `ReadP` parser: the expanded type is `readP_to_S :: ReadP a -> String -> [(a,String)]`

readS_to_P :: ReadS a -> ReadP a

Converts a Haskell ReadS-style function into a parser. Warning: This introduces local backtracking in the resulting parser, and therefore a possible inefficiency.

# Properties

The following are QuickCheck specifications of what the combinators do. These can be seen as formal specifications of the behavior of the combinators.

We use bags to give semantics to the combinators.

     type Bag a = [a]

Equality on bags does not care about the order of elements.

     (=~) :: Ord a => Bag a -> Bag a -> Bool
     xs =~ ys = sort xs == sort ys

A special equality operator to avoid unresolved overloading when testing the properties.

     (=~.) :: Bag (Int,String) -> Bag (Int,String) -> Bool
     (=~.) = (=~)

Here follow the properties:

     prop_Get_Nil =
       readP_to_S get [] =~ []

     prop_Get_Cons c s =
       readP_to_S get (c:s) =~ [(c,s)]

     prop_Look s =
       readP_to_S look s =~ [(s,s)]

     prop_Fail s =
       readP_to_S pfail s =~. []

     prop_Return x s =
       readP_to_S (return x) s =~. [(x,s)]

     prop_Bind p k s =
       readP_to_S (p >>= k) s =~.
         [ ys''
         | (x,s') <- readP_to_S p s
         , ys''   <- readP_to_S (k (x::Int)) s'
         ]

     prop_Plus p q s =
       readP_to_S (p +++ q) s =~.
         (readP_to_S p s ++ readP_to_S q s)

     prop_LeftPlus p q s =
       readP_to_S (p <++ q) s =~.
         (readP_to_S p s +<+ readP_to_S q s)
      where
       [] +<+ ys = ys
       xs +<+ _  = xs

     prop_Gather s =
       forAll readPWithoutReadS $ \p ->
         readP_to_S (gather p) s =~
           [ ((pre,x::Int),s')
           | (x,s') <- readP_to_S p s
           , let pre = take (length s - length s') s
           ]

     prop_String_Yes this s =
       readP_to_S (string this) (this ++ s) =~
         [(this,s)]

     prop_String_Maybe this s =
       readP_to_S (string this) s =~
         [(this, drop (length this) s) | this `isPrefixOf` s]

     prop_Munch p s =
       readP_to_S (munch p) s =~
         [(takeWhile p s, dropWhile p s)]

     prop_Munch1 p s =
       readP_to_S (munch1 p) s =~
         [(res,s') | let (res,s') = (takeWhile p s, dropWhile p s), not (null res)]

     prop_Choice ps s =
       readP_to_S (choice ps) s =~.
         readP_to_S (foldr (+++) pfail ps) s

     prop_ReadS r s =
       readP_to_S (readS_to_P r) s =~. r s